Обробники подій ОбробкаОтриманняПодання та ОбробкаОтриманняПолівПодання

Див. також

Область застосування: керований застосунок, мобільний застосунок.

1. За допомогою цих обробників модуля менеджера об'єкта можна перевизначити подання об'єкта інформаційної бази, яке виводиться в полях форм і в списках.
Приклад реалізації:

Процедура ОбробкаОтриманняПолівПодання(Поля, СтандартнаОбробка)
    Поля.Додати("Найменування");
    Поля.Додати("Дата");
    СтандартнаОбробка = Хибність;
КінецьПроцедури

Процедура ОбробкаОтриманняПодання(Дані, Подання, СтандартнаОбробка)
    Найменування = ?(ПорожнійРядок(Дані.Найменування), НСтр("uk = 'Без опису'"), Дані.Найменування);
    Дата = Формат(Дані.Дата, ?(ОтриматиФункціональнуОпцію("ВикористовуватиДатуІЧасУСтрокахЗавдань"), "ДЛФ=DT", "ДЛФ=D"));
    Подання = СтрШаблон(НСтр("uk = '%1 від %2'"), Найменування, Дата);
    СтандартнаОбробка = Хибність;
КінецьПроцедури

2. Обробники викликаються за будь-якої потреби отримання подання будь-якого об'єкта інформаційної бази. Тому надлишкові дані або неправильний вибір даних для формування подання можуть призвести до істотного уповільнення роботи системи.

Також не слід виконувати в цих обробниках запити або отримання об'єктів інформаційної бази (зокрема, заборонені звернення до реквізитів об'єктів посилальних типів через крапку, що призводить до читання всього об'єкта цілком із бази даних). Також небажано використовувати отримання подання та реквізитів посилань.

3. Обробники можуть бути також викликані, зокрема, під час запису та видалення об'єкта в режимі обміну даними. Подання об'єкта при цьому запитується для формування запису в журналі реєстрації. Тому до них висуваються ті самі вимоги, що й до логіки реєстрації об'єктів - див. п. 1.2 Розробка планів обміну з відборами.

Ці вимоги також справедливі під час розробки планів обміну для синхронізації з іншими програмами (не РІБ, за правилами конвертації) за допомогою підсистеми «Обмін даними» Бібліотеки стандартних підсистем.
Наприклад, неприпустимо звертатися до визначених елементів, які ще могли не бути завантажені в базу або, навпаки, вже видалені під час обміну даними:

Процедура ОбробкаОтриманняПодання(Дані, Подання, СтандартнаОбробка)
    
    СтандартнаОбробка = Хибність;
    Якщо Дані.ВидОсвіти = Довідники.ВидиОсвітиФізичнихОсіб.ПіслявузівськаОсвіта Тоді
        Подання = НСтр("uk = 'Післявузівська освіта'"); 
    Інакше
        ...

4. Під час реалізації обробників слід також враховувати вимоги щодо підтримки товстого клієнта, керованого застосунку, клієнт-сервера.

Див. також

• Отримання подань для посилальних значень у табличному документі
• Користувацькі подання об'єктів